add cmake build scripts

AUTHORS

+Belledonne Communications SARL <contact@belledonne-communications.com>
+

CMakeLists.txt

+############################################################################
+# CMakeLists.txt
+# Copyright (C) 2016  Belledonne Communications, Grenoble France
+#
+############################################################################
+#
+# This program is free software; you can redistribute it and/or
+# modify it under the terms of the GNU General Public License
+# as published by the Free Software Foundation; either version 2
+# of the License, or (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
+#
+############################################################################
+
+cmake_minimum_required(VERSION 3.0)
+project(BCTOOLBOX C CXX)
+
+
+set(PACKAGE "bctoolbox")
+set(PACKAGE_NAME "${PACKAGE}")
+set(PACKAGE_VERSION "0.0.1")
+set(PACKAGE_STRING "${PACKAGE_NAME} ${PACKAGE_VERSION}")
+set(PACKAGE_BUGREPORT "jehan.monnier@linphone.org")
+set(PACKAGE_TARNAME "bctoolbox")
+set(PACKAGE_URL "")
+set(VERSION "${PACKAGE_VERSION}")
+
+
+include(CheckLibraryExists)
+include(CheckSymbolExists)
+include(CheckCSourceCompiles)
+include(CMakePushCheckState)
+
+set(MSVC_INCLUDE_DIR "${CMAKE_CURRENT_SOURCE_DIR}/include/MSVC")
+if(MSVC)
+	list(APPEND CMAKE_REQUIRED_INCLUDES ${MSVC_INCLUDE_DIR})
+endif()
+list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")
+
+find_package(PolarSSL REQUIRED)
+
+set(prefix ${CMAKE_INSTALL_PREFIX})
+set(exec_prefix ${prefix}/bin)
+set(libdir ${prefix}/lib)
+set(includedir ${prefix}/include)
+
+get_filename_component(polarssl_library_path "${POLARSSL_LIBRARIES}" PATH)
+set(LIBS_PRIVATE "${LIBS_PRIVATE} -L${polarssl_library_path} -lpolarssl")
+configure_file(${CMAKE_CURRENT_SOURCE_DIR}/bctoolbox.pc.in ${CMAKE_CURRENT_BINARY_DIR}/bctoolbox.pc)
+install(FILES ${CMAKE_CURRENT_BINARY_DIR}/bctoolbox.pc DESTINATION lib/pkgconfig)
+
+
+include_directories(
+	include
+	src
+	${POLARSSL_INCLUDE_DIRS}
+)
+if(MSVC)
+	include_directories(${MSVC_INCLUDE_DIR})
+endif()
+
+set(STRICT_OPTIONS_CPP )
+set(STRICT_OPTIONS_C )
+if(NOT MSVC)
+	list(APPEND STRICT_OPTIONS_CPP "-Wall" "-Wuninitialized")
+	if(CMAKE_C_COMPILER_ID STREQUAL "Clang")
+		list(APPEND STRICT_OPTIONS_CPP "-Wno-error=unknown-warning-option" "-Qunused-arguments" "-Wno-tautological-compare" "-Wno-builtin-requires-header" "-Wno-unused-function" "-Wno-gnu-designator" "-Wno-array-bounds")
+	elseif(CMAKE_C_COMPILER_ID STREQUAL "GNU")
+		list(APPEND STRICT_OPTIONS_CPP "-Wno-error=pragmas")
+	endif()
+	if(APPLE)
+		list(APPEND STRICT_OPTIONS_CPP "-Wno-error=unknown-warning-option" "-Qunused-arguments" "-Wno-tautological-compare" "-Wno-unused-function" "-Wno-array-bounds")
+	endif()
+	if(ENABLE_STRICT)
+		list(APPEND STRICT_OPTIONS_CPP "-Werror" "-Wno-error=unknown-pragmas" "-Wuninitialized" "-fno-strict-aliasing")
+		list(APPEND STRICT_OPTIONS_C "-Wdeclaration-after-statement" "-Wstrict-prototypes" "-Wno-error=strict-prototypes")
+	endif()
+endif()
+if(STRICT_OPTIONS_CPP)
+	list(REMOVE_DUPLICATES STRICT_OPTIONS_CPP)
+endif()
+if(STRICT_OPTIONS_C)
+	list(REMOVE_DUPLICATES STRICT_OPTIONS_C)
+endif()
+set(LINK_FLAGS )
+if(APPLE)
+	list(APPEND LINK_FLAGS "-framework Foundation")
+	if(IOS)
+		list(APPEND LINK_FLAGS "-framework CoreFoundation" "-framework CFNetwork" "-framework UIKit")
+	endif()
+endif()
+string(REPLACE ";" " " LINK_FLAGS_STR "${LINK_FLAGS}")
+if(WIN32)
+	add_definitions(
+		-DBCTOOLBOX_EXPORTS
+		-DBCTOOLBOX_INTERNAL_EXPORTS
+	)
+endif()
+if(CMAKE_SYSTEM_NAME STREQUAL "WindowsPhone")
+	add_definitions(
+		-DHAVE_COMPILER_TLS
+	)
+endif()
+
+
+if(LINPHONE_BUILDER_GROUP_EXTERNAL_SOURCE_PATH_BUILDERS)
+	set(EXPORT_TARGETS_NAME "LinphoneBuilder")
+else()
+	set(EXPORT_TARGETS_NAME "BcToolbox")
+endif()
+
+add_compile_options(${STRICT_OPTIONS_CPP} ${STRICT_OPTIONS_C})
+
+
+add_subdirectory(include)
+add_subdirectory(src)
+
+include(CMakePackageConfigHelpers)
+write_basic_package_version_file(
+	"${CMAKE_CURRENT_BINARY_DIR}/BcToolboxConfigVersion.cmake"
+	VERSION ${PACKAGE_VERSION}
+	COMPATIBILITY AnyNewerVersion
+)
+export(EXPORT ${EXPORT_TARGETS_NAME}Targets
+	FILE "${CMAKE_CURRENT_BINARY_DIR}/BcToolboxTargets.cmake"
+)
+configure_file(cmake/BcToolboxConfig.cmake.in
+	"${CMAKE_CURRENT_BINARY_DIR}/BcToolboxConfig.cmake"
+	@ONLY
+)
+
+set(ConfigPackageLocation lib/cmake/BcToolbox)
+install(EXPORT ${EXPORT_TARGETS_NAME}Targets
+	FILE BcToolboxTargets.cmake
+	DESTINATION ${ConfigPackageLocation}
+)
+install(FILES
+	"${CMAKE_CURRENT_BINARY_DIR}/BcToolboxConfig.cmake"
+	"${CMAKE_CURRENT_BINARY_DIR}/BcToolboxConfigVersion.cmake"
+	DESTINATION ${ConfigPackageLocation}
+)

README

+cmake .  -DCMAKE_INSTALL_PREFIX=<polarssl prefix>

bctoolbox.pc.in

+# This is a comment
+prefix=@prefix@
+exec_prefix=@exec_prefix@
+includedir=@includedir@
+
+Name: bctoolbox 
+Description: A common set of tools used by Belledonne Communications's softwares 
+Requires.private: @REQUIRES_PRIVATE@ @TLS_PC@
+Version: @VERSION@
+Libs: -L@libdir@ -lbctoolbox
+Libs.private: @LIBS_PRIVATE@
+Cflags: -I@includedir@ 

cmake/BcToolboxConfig.cmake.in

+############################################################################
+# BcToolboxConfig.cmake
+# Copyright (C) 2015  Belledonne Communications, Grenoble France
+#
+############################################################################
+#
+# This program is free software; you can redistribute it and/or
+# modify it under the terms of the GNU General Public License
+# as published by the Free Software Foundation; either version 2
+# of the License, or (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
+#
+############################################################################
+#
+# Config file for the belle-sip package.
+# It defines the following variables:
+#
+#  BCTOOLBOX_FOUND - system has bctoolbox
+#  BCTOOLBOX_INCLUDE_DIRS - the bctoolbox include directory
+#  BCTOOLBOX_LIBRARIES - The libraries needed to use bctoolbox
+#  BCTOOLBOX_LDFLAGS - The linking flags needed to use bctoolbox
+
+if(NOT LINPHONE_BUILDER_GROUP_EXTERNAL_SOURCE_PATH_BUILDERS)
+	include("${CMAKE_CURRENT_LIST_DIR}/BcToolboxTargets.cmake")
+endif()
+
+get_filename_component(BCTOOLBOX_CMAKE_DIR "${CMAKE_CURRENT_LIST_FILE}" PATH)
+if(LINPHONE_BUILDER_GROUP_EXTERNAL_SOURCE_PATH_BUILDERS)
+	set(BCTOOLBOX_INCLUDE_DIRS "${EP_bctoolbox_INCLUDE_DIR}")
+else()
+	set(BCTOOLBOX_INCLUDE_DIRS "${BCTOOLBOX_CMAKE_DIR}/../../../include")
+endif()
+set(BCTOOLBOX_LIBRARIES bctoolbox)
+set(BCTOOLBOX_LDFLAGS "@LINK_FLAGS_STR@")
+set(BCTOOLBOX_FOUND 1)

cmake/FindPolarSSL.cmake

+############################################################################
+# FindPolarSSL.txt
+# Copyright (C) 2015  Belledonne Communications, Grenoble France
+#
+############################################################################
+#
+# This program is free software; you can redistribute it and/or
+# modify it under the terms of the GNU General Public License
+# as published by the Free Software Foundation; either version 2
+# of the License, or (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
+#
+############################################################################
+#
+# - Find the polarssl include file and library
+#
+#  POLARSSL_FOUND - system has polarssl
+#  POLARSSL_INCLUDE_DIRS - the polarssl include directory
+#  POLARSSL_LIBRARIES - The libraries needed to use polarssl
+
+include(CMakePushCheckState)
+include(CheckIncludeFile)
+include(CheckCSourceCompiles)
+include(CheckSymbolExists)
+
+set(_POLARSSL_ROOT_PATHS
+	${CMAKE_INSTALL_PREFIX}
+)
+
+find_path(POLARSSL_INCLUDE_DIRS
+	NAMES polarssl/ssl.h
+	HINTS _POLARSSL_ROOT_PATHS
+	PATH_SUFFIXES include
+)
+if(POLARSSL_INCLUDE_DIRS)
+	set(HAVE_POLARSSL_SSL_H 1)
+endif()
+
+find_library(POLARSSL_LIBRARIES
+	NAMES polarssl mbedtls
+	HINTS _POLARSSL_ROOT_PATHS
+	PATH_SUFFIXES bin lib
+)
+
+if(POLARSSL_LIBRARIES)
+	cmake_push_check_state(RESET)
+	set(CMAKE_REQUIRED_INCLUDES ${POLARSSL_INCLUDE_DIRS})
+	set(CMAKE_REQUIRED_LIBRARIES ${POLARSSL_LIBRARIES})
+	check_c_source_compiles("#include <polarssl/version.h>
+#include <polarssl/x509.h>
+#if POLARSSL_VERSION_NUMBER >= 0x01030000
+#include <polarssl/compat-1.2.h>
+#endif
+int main(int argc, char *argv[]) {
+x509parse_crtpath(0,0);
+return 0;
+}"
+		X509PARSE_CRTPATH_OK)
+	check_symbol_exists(ssl_get_dtls_srtp_protection_profile "polarssl/ssl.h" HAVE_SSL_GET_DTLS_SRTP_PROTECTION_PROFILE)
+	cmake_pop_check_state()
+endif()
+
+include(FindPackageHandleStandardArgs)
+find_package_handle_standard_args(PolarSSL
+	DEFAULT_MSG
+	POLARSSL_INCLUDE_DIRS POLARSSL_LIBRARIES HAVE_POLARSSL_SSL_H
+)
+
+mark_as_advanced(POLARSSL_INCLUDE_DIRS POLARSSL_LIBRARIES HAVE_POLARSSL_SSL_H X509PARSE_CRTPATH_OK HAVE_SSL_GET_DTLS_SRTP_PROTECTION_PROFILE)

include/CMakeLists.txt

+############################################################################
+# CMakeLists.txt
+# Copyright (C) 2016  Belledonne Communications, Grenoble France
+#
+############################################################################
+#
+# This program is free software; you can redistribute it and/or
+# modify it under the terms of the GNU General Public License
+# as published by the Free Software Foundation; either version 2
+# of the License, or (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
+#
+############################################################################
+
+set(HEADER_FILES
+	crypto.h
+)
+
+set(BCTOOLBOX_HEADER_FILES )
+foreach(HEADER_FILE ${HEADER_FILES})
+	list(APPEND BCTOOLBOX_HEADER_FILES "${CMAKE_CURRENT_LIST_DIR}/bctoolbox/${HEADER_FILE}")
+endforeach()
+set(BCTOOLBOX_HEADER_FILES ${BCTOOLBOX_HEADER_FILES} PARENT_SCOPE)
+
+install(FILES ${BCTOOLBOX_HEADER_FILES}
+        DESTINATION include/bctoolbox
+        PERMISSIONS OWNER_READ OWNER_WRITE GROUP_READ WORLD_READ)

include/bctoolbox/crypto.h

+/*
+chrypto.h
+Copyright (C) 2016  Belledonne Communications SARL
+
+This program is free software; you can redistribute it and/or
+modify it under the terms of the GNU General Public License
+as published by the Free Software Foundation; either version 2
+of the License, or (at your option) any later version.
+
+This program is distributed in the hope that it will be useful,
+but WITHOUT ANY WARRANTY; without even the implied warranty of
+MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+GNU General Public License for more details.
+
+You should have received a copy of the GNU General Public License
+along with this program; if not, write to the Free Software
+Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
+*/
+#ifndef BCTOOLBOX_CRYPTO_H
+#define BCTOOLBOX_CRYPTO_H
+int dummy(void);
+#endif

src/CMakeLists.txt

+############################################################################
+# CMakeLists.txt
+# Copyright (C) 2016  Belledonne Communications, Grenoble France
+#
+############################################################################
+#
+# This program is free software; you can redistribute it and/or
+# modify it under the terms of the GNU General Public License
+# as published by the Free Software Foundation; either version 2
+# of the License, or (at your option) any later version.
+#
+# This program is distributed in the hope that it will be useful,
+# but WITHOUT ANY WARRANTY; without even the implied warranty of
+# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+# GNU General Public License for more details.
+#
+# You should have received a copy of the GNU General Public License
+# along with this program; if not, write to the Free Software
+# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
+#
+############################################################################
+
+
+set(BCTOOLBOX_SOURCE_FILES
+	crypto.c
+)
+
+
+if(ENABLE_STATIC)
+	add_library(bctoolbox STATIC ${BCTOOLBOX_HEADER_FILES} ${BCTOOLBOX_SOURCE_FILES})
+else()
+	add_library(bctoolbox SHARED ${BCTOOLBOX_HEADER_FILES} ${BCTOOLBOX_SOURCE_FILES})
+	set_target_properties(bctoolbox PROPERTIES VERSION 0.0.0 SOVERSION 0)
+	if(MSVC)
+		if(CMAKE_BUILD_TYPE STREQUAL "Debug")
+			install(FILES ${CMAKE_CURRENT_BINARY_DIR}/Debug/bctoolbox.pdb
+				DESTINATION bin
+				PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE
+			)
+		endif()
+	endif()
+endif()
+
+list(APPEND INCLUDES ${POLARSSL_INCLUDE_DIR})
+list(APPEND LIBS ${POLARSSL_LIBRARIES})
+
+
+target_include_directories(bctoolbox PUBLIC ${INCLUDES})
+target_link_libraries(bctoolbox ${LIBS})
+
+install(TARGETS bctoolbox EXPORT ${EXPORT_TARGETS_NAME}Targets
+	RUNTIME DESTINATION bin
+	LIBRARY DESTINATION lib
+	ARCHIVE DESTINATION lib
+	PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE
+)

src/crypto.c

+/*
+chrypto.c
+Copyright (C) 2016  Belledonne Communications SARL
+
+This program is free software; you can redistribute it and/or
+modify it under the terms of the GNU General Public License
+as published by the Free Software Foundation; either version 2
+of the License, or (at your option) any later version.
+
+This program is distributed in the hope that it will be useful,
+but WITHOUT ANY WARRANTY; without even the implied warranty of
+MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
+GNU General Public License for more details.
+
+You should have received a copy of the GNU General Public License
+along with this program; if not, write to the Free Software
+Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
+*/
+int dummy(void) {
+	int a=5;
+	return a;
+}
+