soci.ads 12.2 KB
Newer Older
1 2 3 4 5 6 7 8 9 10 11 12 13 14 15 16 17 18 19 20 21 22 23 24 25 26 27 28 29 30 31 32 33 34 35 36 37 38 39 40 41 42 43 44 45 46 47 48 49 50 51 52 53 54 55 56 57 58 59 60 61 62 63 64 65 66 67 68 69 70 71 72 73 74 75 76 77 78 79 80 81 82 83 84 85 86 87 88 89 90 91 92 93 94 95 96 97 98 99 100 101 102 103 104 105 106 107 108 109 110 111 112 113 114 115 116 117 118 119 120 121 122 123 124 125 126 127 128 129 130 131 132 133 134 135 136 137 138 139 140 141 142 143 144 145 146 147 148 149 150 151 152 153 154 155 156 157 158 159 160 161 162 163 164 165 166 167 168 169 170 171 172 173 174 175 176 177 178 179 180 181 182 183 184 185 186 187 188 189 190 191 192 193 194 195 196 197 198 199 200 201 202 203 204 205 206 207 208 209 210 211 212 213 214 215 216 217 218 219 220 221 222 223 224 225 226 227 228 229 230 231 232 233 234 235 236 237 238 239 240 241 242 243 244 245 246 247 248 249 250 251 252 253 254 255 256 257 258 259 260 261 262 263 264 265 266 267 268 269 270 271 272 273 274 275 276 277 278 279 280 281 282 283 284 285 286 287 288 289 290 291 292 293 294 295 296 297 298 299 300 301 302 303 304 305 306 307 308 309 310 311 312 313 314 315 316 317 318 319 320 321 322 323 324 325 326 327 328 329 330 331 332 333 334 335 336 337 338 339 340 341 342 343 344 345 346 347 348 349 350 351 352 353 354 355 356 357 358 359 360 361 362 363 364 365 366 367 368 369 370 371 372 373 374 375 376 377 378 379 380 381 382 383 384 385 386 387 388 389 390 391 392 393 394 395 396 397 398 399 400 401 402 403 404 405 406 407 408 409 410 411 412 413 414 415 416 417 418 419 420 421 422 423 424 425 426 427 428 429 430 431 432 433 434 435 436 437 438 439 440 441 442 443 444 445 446 447 448 449 450 451 452 453 454 455 456 457 458 459 460 461 462 463 464 465 466 467 468 469 470 471 472 473 474 475 476 477 478 479 480 481 482 483 484 485 486
--
--  Thin wrapper for the simple interface of the SOCI database access library.
--
--  Copyright (C) 2008-2011 Maciej Sobczak
--  Distributed under the Boost Software License, Version 1.0.
--  (See accompanying file LICENSE_1_0.txt or copy at
--  http://www.boost.org/LICENSE_1_0.txt)

with Ada.Calendar;
with Interfaces.C;

private with System;
private with Ada.Finalization;

package SOCI is

   --
   --  General exception related to database and library usage.
   --

   Database_Error : exception;

   --
   --  Session.
   --

   type Session is tagged limited private;

   not overriding
   function Make_Session (Connection_String : in String) return Session;

   not overriding
   procedure Open (This : in out Session; Connection_String : in String);

   not overriding
   procedure Close (This : in out Session);

   not overriding
   function Is_Open (This : in Session) return Boolean;

   --  Transaction management.

   not overriding
   procedure Start (This : in Session);

   not overriding
   procedure Commit (This : in Session);

   not overriding
   procedure Rollback (This : in Session);

   --  Immediate query execution.
   not overriding
   procedure Execute (This : in Session; Query : in String);

   --
   --  Connection pool management.
   --

   type Connection_Pool (Size : Positive) is tagged limited private;

   not overriding
   procedure Open
     (This : in out Connection_Pool;
      Position : in Positive;
      Connection_String : in String);

   not overriding
   procedure Close (This : in out Connection_Pool; Position : in Positive);

   not overriding
   procedure Lease (This : in out Connection_Pool; S : in out Session'Class);

   --
   --  Statement.
   --

   type Statement (<>) is tagged limited private;

   type Data_State is (Data_Null, Data_Not_Null);

   type Into_Position is private;

   type Vector_Index is new Natural;

   not overriding
   function Make_Statement (Sess : in Session'Class) return Statement;

   --  Statement preparation and execution.

   not overriding
   procedure Prepare (This : in Statement; Query : in String);

   not overriding
   procedure Execute
     (This : in Statement;
      With_Data_Exchange : in Boolean := False);

   not overriding
   function Execute
     (This : in Statement;
      With_Data_Exchange : in Boolean := False) return Boolean;

   not overriding
   function Fetch (This : in Statement) return Boolean;

   not overriding
   function Got_Data (This : in Statement) return Boolean;

   --
   --  Data items handling.
   --

   --  Database-specific types.
   --  These types are most likely identical to standard Integer,
   --  Long_Long_Integer and Long_Float, but are defined distinctly
   --  to avoid interfacing problems with other compilers.

   type DB_Integer is new Interfaces.C.int;
   type DB_Long_Long_Integer is new Interfaces.Integer_64;
   type DB_Long_Float is new Interfaces.C.double;

   --  Creation of single into elements.

   not overriding
   function Into_String (This : in Statement) return Into_Position;

   not overriding
   function Into_Integer (This : in Statement) return Into_Position;

   not overriding
   function Into_Long_Long_Integer (This : in Statement) return Into_Position;

   not overriding
   function Into_Long_Float (This : in Statement) return Into_Position;

   not overriding
   function Into_Time (This : in Statement) return Into_Position;

   --  Creation of vector into elements.

   not overriding
   function Into_Vector_String (This : in Statement) return Into_Position;

   not overriding
   function Into_Vector_Integer (This : in Statement) return Into_Position;

   not overriding
   function Into_Vector_Long_Long_Integer (This : in Statement) return Into_Position;

   not overriding
   function Into_Vector_Long_Float (This : in Statement) return Into_Position;

   not overriding
   function Into_Vector_Time (This : in Statement) return Into_Position;

   --  Inspection of single into elements.

   not overriding
   function Get_Into_State
     (This : in Statement;
      Position : in Into_Position)
     return Data_State;

   not overriding
   function Get_Into_String
     (This : in Statement;
      Position : in Into_Position)
     return String;

   not overriding
   function Get_Into_Integer
     (This : in Statement;
      Position : in Into_Position)
     return DB_Integer;

   not overriding
   function Get_Into_Long_Long_Integer
     (This : in Statement;
      Position : in Into_Position)
     return DB_Long_Long_Integer;

   not overriding
   function Get_Into_Long_Float
     (This : in Statement;
      Position : in Into_Position)
     return DB_Long_Float;

   not overriding
   function Get_Into_Time
     (This : in Statement;
      Position : in Into_Position)
     return Ada.Calendar.Time;

   --  Inspection of vector into elements.

   not overriding
   function Get_Into_Vectors_Size (This : in Statement) return Natural;

   not overriding
   function Into_Vectors_First_Index (This : in Statement) return Vector_Index;

   not overriding
   function Into_Vectors_Last_Index (This : in Statement) return Vector_Index;

   not overriding
   procedure Into_Vectors_Resize (This : in Statement; New_Size : in Natural);

   not overriding
   function Get_Into_Vector_State
     (This : in Statement;
      Position : in Into_Position;
      Index : in Vector_Index)
     return Data_State;

   not overriding
   function Get_Into_Vector_String
     (This : in Statement;
      Position : in Into_Position;
      Index : in Vector_Index)
     return String;

   not overriding
   function Get_Into_Vector_Integer
     (This : in Statement;
      Position : in Into_Position;
      Index : in Vector_Index)
     return DB_Integer;

   not overriding
   function Get_Into_Vector_Long_Long_Integer
     (This : in Statement;
      Position : in Into_Position;
      Index : in Vector_Index)
     return DB_Long_Long_Integer;

   not overriding
   function Get_Into_Vector_Long_Float
     (This : in Statement;
      Position : in Into_Position;
      Index : in Vector_Index)
     return DB_Long_Float;

   not overriding
   function Get_Into_Vector_Time
     (This : in Statement;
      Position : in Into_Position;
      Index : in Vector_Index)
     return Ada.Calendar.Time;

   --  Creation of single use elements.

   not overriding
   procedure Use_String (This : in Statement; Name : in String);

   not overriding
   procedure Use_Integer (This : in Statement; Name : in String);

   not overriding
   procedure Use_Long_Long_Integer (This : in Statement; Name : in String);

   not overriding
   procedure Use_Long_Float (This : in Statement; Name : in String);

   not overriding
   procedure Use_Time (This : in Statement; Name : in String);

   --  Creation of vector use elements.

   not overriding
   procedure Use_Vector_String (This : in Statement; Name : in String);

   not overriding
   procedure Use_Vector_Integer (This : in Statement; Name : in String);

   not overriding
   procedure Use_Vector_Long_Long_Integer (This : in Statement; Name : in String);

   not overriding
   procedure Use_Vector_Long_Float (This : in Statement; Name : in String);

   not overriding
   procedure Use_Vector_Time (This : in Statement; Name : in String);

   --  Modifiers for single use elements.

   not overriding
   procedure Set_Use_State
     (This : in Statement;
      Name : in String;
      State : in Data_State);

   not overriding
   procedure Set_Use_String
     (This : in Statement;
      Name : in String;
      Value : in String);

   not overriding
   procedure Set_Use_Integer
     (This : in Statement;
      Name : in String;
      Value : in DB_Integer);

   not overriding
   procedure Set_Use_Long_Long_Integer
     (This : in Statement;
      Name : in String;
      Value : in DB_Long_Long_Integer);

   not overriding
   procedure Set_Use_Long_Float
     (This : in Statement;
      Name : in String;
      Value : in DB_Long_Float);

   not overriding
   procedure Set_Use_Time
     (This : in Statement;
      Name : in String;
      Value : in Ada.Calendar.Time);

   --  Modifiers for vector use elements.

   not overriding
   function Get_Use_Vectors_Size (This : in Statement) return Natural;

   not overriding
   function Use_Vectors_First_Index (This : in Statement) return Vector_Index;

   not overriding
   function Use_Vectors_Last_Index (This : in Statement) return Vector_Index;

   not overriding
   procedure Use_Vectors_Resize (This : in Statement; New_Size : in Natural);

   not overriding
   procedure Set_Use_Vector_State
     (This : in Statement;
      Name : in String;
      Index : in Vector_Index;
      State : in Data_State);

   not overriding
   procedure Set_Use_Vector_String
     (This : in Statement;
      Name : in String;
      Index : in Vector_Index;
      Value : in String);

   not overriding
   procedure Set_Use_Vector_Integer
     (This : in Statement;
      Name : in String;
      Index : in Vector_Index;
      Value : in DB_Integer);

   not overriding
   procedure Set_Use_Vector_Long_Long_Integer
     (This : in Statement;
      Name : in String;
      Index : in Vector_Index;
      Value : in DB_Long_Long_Integer);

   not overriding
   procedure Set_Use_Vector_Long_Float
     (This : in Statement;
      Name : in String;
      Index : in Vector_Index;
      Value : in DB_Long_Float);

   not overriding
   procedure Set_Use_Vector_Time
     (This : in Statement;
      Name : in String;
      Index : in Vector_Index;
      Value : in Ada.Calendar.Time);

   --  Inspection of single use elements.
   --
   --  Note: Use elements can be modified by the database if they
   --        are bound to out and inout parameters of stored procedures
   --        (although this is not supported by all database backends).
   --        This feature is available only for single use elements.

   not overriding
   function Get_Use_State
     (This : in Statement;
      Name : in String)
     return Data_State;

   not overriding
   function Get_Use_String
     (This : in Statement;
      Name : in String)
     return String;

   not overriding
   function Get_Use_Integer
     (This : in Statement;
      Name : in String)
     return DB_Integer;

   not overriding
   function Get_Use_Long_Long_Integer
     (This : in Statement;
      Name : in String)
     return DB_Long_Long_Integer;

   not overriding
   function Get_Use_Long_Float
     (This : in Statement;
      Name : in String)
     return DB_Long_Float;

   not overriding
   function Get_Use_Time
     (This : in Statement;
      Name : in String)
     return Ada.Calendar.Time;

private

   --  Connection pool and supporting types.

   type Connection_Array is array (Positive range <>) of Session;
   type Used_Array is array (Positive range <>) of Boolean;

   --  Protected state for the connection pool.
   protected type Connection_Pool_PS (Size : Positive) is

      procedure Open (Position : in Positive; Connection_String : in String);
      procedure Close (Position : in Positive);

      entry Lease (S : in out Session'Class);
      procedure Give_Back (Position : in Positive);

   private

      Connections : Connection_Array (1 .. Size);
      Is_Used : Used_Array (1 .. Size) := (others => False);
      Available : Boolean := True;

   end Connection_Pool_PS;
   type Connection_Pool_PS_Ptr is access all Connection_Pool_PS;

   type Connection_Pool (Size : Positive) is tagged limited record
      Pool : aliased Connection_Pool_PS (Size);
   end record;

   --  Session and supporting types.

   type Session_Handle is new System.Address;

   Null_Session_Handle : constant Session_Handle :=
     Session_Handle (System.Null_Address);

   type Session is new Ada.Finalization.Limited_Controlled with record
      Handle : Session_Handle;
      Initialized : Boolean := False;
      Belongs_To_Pool : Boolean := False;
      Pool : Connection_Pool_PS_Ptr;
      Position_In_Pool : Positive;
   end record;

   overriding
   procedure Finalize (This : in out Session);

   --  Statement and supporting types.

   type Statement_Handle is new System.Address;

   Null_Statement_Handle : constant Statement_Handle :=
     Statement_Handle (System.Null_Address);

   type Statement is new Ada.Finalization.Limited_Controlled with record
      Handle : Statement_Handle;
      Initialized : Boolean := False;
   end record;

   overriding
   procedure Finalize (This : in out Statement);

   type Into_Position is new Natural;

end SOCI;