Extract Particles code to an independent library

QtQuick clients that do not use particles features should not have
to load these classes.

Task-number: QTBUG-25178
Change-Id: Ib15f7655dc4d821595e06f9160d2770375279027
Reviewed-by: Glenn Watson <glenn.watson@nokia.com>

modules/qt_quickparticles.pri

+QT.quickparticles.VERSION = 5.0.0
+QT.quickparticles.MAJOR_VERSION = 5
+QT.quickparticles.MINOR_VERSION = 0
+QT.quickparticles.PATCH_VERSION = 0
+
+QT.quickparticles.name = QtQuickParticles
+QT.quickparticles.bins = $$QT_MODULE_BIN_BASE
+QT.quickparticles.includes = $$QT_MODULE_INCLUDE_BASE $$QT_MODULE_INCLUDE_BASE/QtQuickParticles
+QT.quickparticles.private_includes = $$QT_MODULE_INCLUDE_BASE/QtQuickParticles/$$QT.quickparticles.VERSION
+QT.quickparticles.sources = $$QT_MODULE_BASE/src/particles
+QT.quickparticles.libs = $$QT_MODULE_LIB_BASE
+QT.quickparticles.plugins = $$QT_MODULE_PLUGIN_BASE
+QT.quickparticles.imports = $$QT_MODULE_IMPORT_BASE
+QT.quickparticles.depends = qml quick
+QT.quickparticles.DEFINES = QT_QUICKPARTICLES_LIB
+
+QT_CONFIG += quickparticles

src/imports/particles/particles.pro

@@ -5,7 +5,7 @@ include(../qimportbase.pri)
 SOURCES += \
     plugin.cpp
 
-QT += quick-private qml-private
+QT += quick-private quickparticles-private qml-private
 
 OTHER_FILES += \
     qmldir

src/quick/particles/particles.pri → src/particles/particles.pri

@@ -28,7 +28,8 @@ HEADERS += \
     $$PWD/qquickv8particledata_p.h \
     $$PWD/qquickrectangleextruder_p.h \
     $$PWD/qquickparticlegroup_p.h \
-    $$PWD/qquickgroupgoal_p.h
+    $$PWD/qquickgroupgoal_p.h \
+    $$PWD/qtquickparticlesglobal_p.h
 
 SOURCES += \
     $$PWD/qquickangledirection.cpp \

src/particles/particles.pro

+load(qt_module)
+
+TARGET = QtQuickParticles
+
+CONFIG += module
+CONFIG += dll warn_on
+MODULE_PRI = ../../modules/qt_quickparticles.pri
+
+QT = core-private gui-private v8-private qml-private quick-private
+
+DEFINES   += QT_BUILD_QUICKPARTICLES_LIB QT_NO_URL_CAST_FROM_STRING QT_NO_INTEGER_EVENT_COORDINATES
+win32-msvc*:DEFINES *= _CRT_SECURE_NO_WARNINGS
+solaris-cc*:QMAKE_CXXFLAGS_RELEASE -= -O2
+
+exists("qqml_enable_gcov") {
+    QMAKE_CXXFLAGS = -fprofile-arcs -ftest-coverage -fno-elide-constructors
+    LIBS += -lgcov
+}
+
+MODULE = quickparticles
+load(qt_module_config)
+
+include(particles.pri)
+
+mac {
+    # FIXME: this is a workaround for broken qmake logic in qtAddModule()
+    # This function refuses to use frameworks unless the framework exists on
+    # the filesystem at the time qmake is run, resulting in a build failure
+    # if QtQuick is qmaked before QtQml is built and frameworks are
+    # in use. qtAddLibrary() contains correct logic to deal with this, so
+    # we'll explicitly call that for now.
+    load(qt)
+    LIBS -= -lQtQml        # in non-framework builds, these should be re-added
+    LIBS -= -lQtQml_debug  # within the qtAddLibrary if appropriate, so no
+    qtAddLibrary(QtQml)    # harm done :)
+    LIBS -= -lQtQuick
+    LIBS -= -lQtQuick_debug
+    qtAddLibrary(QtQuick)
+}
+